home *** CD-ROM | disk | FTP | other *** search
/ BBS Toolkit / BBS Toolkit.iso / windows / mrun211.zip / MRUN211F.WAS < prev    next >
Text File  |  1993-05-01  |  11KB  |  452 lines
  1. ;MailRun v2.11:  Part F, othercmds
  2. ;1992-1993 Gerald P. Sully, all rights reserved.
  3.  
  4. #comment
  5. **************************************************************************
  6. **************************************************************************
  7. * 
  8. * This file is a grab bag of routines for the following:
  9. * adding an item to Get or Send Mail; adding an item to send a
  10. * command; adding an item to execute a script; displaying the 
  11. * "About MailRun" dialog box.  The appropriate routine is 
  12. * selected with a FLAG.
  13. * 
  14. **************************************************************************
  15. **************************************************************************
  16. #endcomment
  17.  
  18. #define MRUN211F
  19.  
  20. #include "MRUN211.h"
  21.  
  22. string Command, ScriptName, ScriptList, MRunIcons, BBSChoice
  23. integer GetSendRadio, IconIndex
  24.  
  25.  
  26. #comment
  27. *********************************************************************
  28. * 
  29. * MAIN()
  30. * 
  31. * Calls checkchild(), addgetmail(), addsendcommand(), 
  32. * adddoscript(), showabout(), menudim()
  33. * 
  34. * Calls the appropriate function based on the value of
  35. * FLAGS.
  36. * 
  37. *********************************************************************
  38. #endcomment
  39.  
  40. proc main
  41. integer cmdstatus
  42.     menudim()
  43.     checkchild()
  44.     findfirst MailRun
  45.     MailRunTrunc = $FILENAME
  46.     cmdstatus = FLAGS & (AGM + CMD + SCR + ABT)
  47.     switch cmdstatus
  48.         case AGM
  49.             addgetmail()
  50.         endcase
  51.         case CMD
  52.             addsendcommand()
  53.         endcase
  54.         case SCR
  55.             adddoscript()
  56.         endcase
  57.         case ABT
  58.             showabout()
  59.         endcase
  60.     endswitch
  61. endproc
  62.  
  63.  
  64. #comment
  65. *********************************************************************
  66. * 
  67. * ADDGETMAIL()
  68. * 
  69. * Called by main()
  70. * 
  71. * Calls getlastitem(),
  72. * getmailbox(), gettaskstring(), makebbslist(),
  73. * insertitem(), interfaceon()
  74. * 
  75. * Adds a GetMail item to the mailrun.
  76. * 
  77. *********************************************************************
  78. #endcomment
  79.  
  80. proc addgetmail
  81. string GetMailString, GetSendMail, StatString, char
  82. integer dialogstatus, Perm, j
  83.     strextract BBSChoice TaskItem "`t" 3
  84.     strextract char TaskItem "`t" 4
  85.     atoi char j
  86.     makebbslist()
  87.     getmailbox()
  88.     statmsg ""
  89.     interfaceon()
  90.     while 1
  91.         dialogstatus = $DIALOG
  92.         switch dialogstatus
  93.             case 10
  94.                 ;User selected "Add"
  95.                 if GetSendRadio == 1
  96.                     GetSendMail = "GetMail"
  97.                     strfmt StatString "Added to %s:  `"Get QWK Packet`"" BBSChoice
  98.                 else
  99.                     GetSendMail = "SendMail"
  100.                     strfmt StatString "Added to %s:  `"Send REP Packet`"" BBSChoice
  101.                 endif
  102.                 Perm = 2 - PermRadio
  103.                 strfmt GetMailString "1,%d,%s" Perm GetSendMail
  104.                 ;Update MAILRUN.INI, task list
  105.                 j++
  106.                 insertitem(BBSChoice, j, GetMailString)
  107.                 TaskItem = gettaskstring(BBSChoice, j)
  108.                 statmsg StatString
  109.             endcase
  110.             case 11
  111.                 ;User selected "Done"
  112.                 exit
  113.             endcase
  114.             case 170
  115.                 ;User changed BBS with combobox
  116.                 j = getlastitem(BBSChoice)
  117.                 TaskItem = gettaskstring(BBSChoice, j)
  118.             endcase
  119.         endswitch
  120.     endwhile
  121. endproc
  122.  
  123.  
  124. #comment
  125. *********************************************************************
  126. * 
  127. * GETMAILBOX()
  128. * 
  129. * Called by addgetmail()
  130. * 
  131. * Displays the Get/Send Mail dialog box.
  132. * 
  133. *********************************************************************
  134. #endcomment
  135.  
  136. proc getmailbox
  137. PermRadio = 1
  138. GetSendRadio = 1
  139. destroydlg
  140. HelpPage = 8
  141. dialogbox 52 68 243 93 15 "Get/Send Mail" HELPID HelpPage
  142.    radiobutton 16 44 54 14 "Get Mail" GetSendRadio
  143.    radiobutton 16 63 54 14 "Send Mail" endgroup
  144.    radiobutton 94 44 54 14 "Permanent" PermRadio
  145.    radiobutton 94 63 54 14 "Temporary" endgroup
  146.    pushbutton 184 44 40 14 "&Add" normal default
  147.    pushbutton 184 63 40 14 "&Done" normal
  148.    text  52 12 68 8 right "Get/Send Mail for:"
  149.    combobox 124 10 67 41 BBSList BBSChoice sort
  150. enddialog
  151. endproc
  152.  
  153.  
  154. #comment
  155. *********************************************************************
  156. * 
  157. * ADDSENDCOMMAND()
  158. * 
  159. * Called by main()
  160. * 
  161. * Calls getlastitem(),
  162. * gettaskstring(), makebbslist(), interfaceon(),
  163. * sendcommandbox(), insertitem()
  164. * 
  165. * Adds a "SendCommand" item to the mailrun.  A command
  166. * string may contain multiple command lines separated by
  167. * verticle bars.  Successive command lines will be sent
  168. * when the terminal screen is quiet for 15 seconds.
  169. * 
  170. *********************************************************************
  171. #endcomment
  172.  
  173. proc addsendcommand
  174. string CommandString, StatString, char
  175. integer dialogstatus, Perm, j
  176.     strextract BBSChoice TaskItem "`t" 3
  177.     strextract char TaskItem "`t" 4
  178.     atoi char j
  179.     makebbslist()
  180.     sendcommandbox()
  181.     statmsg ""
  182.     interfaceon()
  183.     while 1
  184.         dialogstatus = $DIALOG
  185.         switch dialogstatus
  186.             case 10
  187.                 ;User selected "Add"
  188.                 Perm = 2 - PermRadio
  189.                 strfmt CommandString "1,%d,SendCommand,%s" Perm Command
  190.                 strfmt StatString "Added to %s:  `"Send Command:  %s`"" \
  191.                     BBSChoice Command
  192.                 j++
  193.                 insertitem(BBSChoice, j, CommandString)
  194.                 TaskItem = gettaskstring(BBSChoice, j)
  195.                 statmsg StatString
  196.             endcase
  197.             case 11
  198.                 ;User selected "Done"
  199.                 exit
  200.             endcase
  201.             case 170
  202.                 ;User changed BBS with the combobox
  203.                 j = getlastitem(BBSChoice)
  204.                 TaskItem = gettaskstring(BBSChoice, j)
  205.             endcase
  206.         endswitch
  207.     endwhile
  208. endproc
  209.  
  210.  
  211. #comment
  212. *********************************************************************
  213. * 
  214. * SENDCOMMANDBOX()
  215. * 
  216. * Called by addsendcommand()
  217. * 
  218. * Displays the Send Command dialog box.
  219. * 
  220. *********************************************************************
  221. #endcomment
  222.  
  223. proc sendcommandbox
  224. PermRadio = 2
  225. Command = ""
  226. destroydlg
  227. HelpPage = 11
  228. dialogbox 92 63 196 124 15 "Send Command" HELPID HelpPage
  229.    text  8 39 42 8 right "Command:"
  230.    editbox 54 37 124 11 Command
  231.    radiobutton 32 85 59 11 "Permanent" PermRadio
  232.    radiobutton 32 101 59 11 "Temporary" endgroup
  233.    pushbutton 129 77 40 14 "&Add" normal default
  234.    pushbutton 129 97 40 14 "&Done" normal
  235.    text  30 15 68 8 right "Send Command to:"
  236.    combobox 102 13 65 42 BBSList BBSChoice sort
  237.    text  54 51 97 8 left "Use a vertical bar (`"|`") to"
  238.    text  54 61 97 8 left "separate multiple commands."
  239. enddialog
  240. endproc
  241.  
  242.  
  243. #comment
  244. *********************************************************************
  245. * 
  246. * ADDDOSCRIPT()
  247. * 
  248. * Called by main()
  249. * 
  250. * Calls getlastitem(),
  251. * makebbslist(), makescriptlist(), interfaceon(),
  252. * gettaskstring(), scriptbox(), insertitem()
  253. * 
  254. * Adds a SendScript Item to the mailrun.
  255. * 
  256. *********************************************************************
  257. #endcomment
  258.  
  259. proc adddoscript
  260. string ScriptString, StatString, char
  261. integer dialogstatus, Perm, j
  262.     strextract BBSChoice TaskItem "`t" 3
  263.     strextract char TaskItem "`t" 4
  264.     atoi char j
  265.     makebbslist()
  266.     makescriptlist()
  267.     scriptbox()
  268.     statmsg ""
  269.     interfaceon()
  270.     while dialogstatus != 1
  271.         dialogstatus = $DIALOG
  272.         switch dialogstatus
  273.             case 10
  274.                 ;User chose "Add"
  275.                 Perm = 2 - PermRadio
  276.                 strupr ScriptName
  277.                 strfmt ScriptString "1,%d,SendScript,%s" Perm ScriptName
  278.                 strfmt StatString "Added to %s:  `"Execute Script:  %s`"" \
  279.                     BBSChoice ScriptName
  280.                 j++
  281.                 insertitem(BBSChoice, j, ScriptString)
  282.                 TaskItem = gettaskstring(BBSChoice, j)
  283.                 statmsg StatString
  284.             endcase
  285.             case 11
  286.                 ;User selected "Done"
  287.                 exit
  288.             endcase
  289.             case 170
  290.                 ;User changed BBS with the combobox
  291.                 j = getlastitem(BBSChoice)
  292.                 TaskItem = gettaskstring(BBSChoice, j)
  293.             endcase
  294.         endswitch
  295.     endwhile
  296. endproc
  297.  
  298.  
  299. #comment
  300. *********************************************************************
  301. * 
  302. * MAKESCRIPTLIST()
  303. * 
  304. * Called by adddoscript()
  305. * 
  306. * Calls openfile(), makefullname()
  307. * 
  308. * Creates a list of scripts for display in the scriptbox()
  309. * dialog box script fcombobox.
  310. * 
  311. *********************************************************************
  312. #endcomment
  313.  
  314. proc makescriptlist
  315. string ScriptSpec, NextScript, ScriptLine
  316.     ScriptName = ""
  317.     ScriptList = makefullname(TempDir, "SCRIPTS.TMP")
  318.     openfile(ScriptFile, ScriptList, _CREATE, _TEXT)
  319.     ScriptSpec = makefullname(MailRunDir, "*.WA?")
  320.     findfirst ScriptSpec
  321.     ;Loop through all files in the directory
  322.     while FOUND
  323.         NextScript = $FNAME
  324.         strlwr NextScript
  325.         switch NextScript
  326.             case "MRUN211"
  327.             case "MRUN211A"
  328.             case "MRUN211B"
  329.             case "MRUN211C"
  330.             case "MRUN211D"
  331.             case "MRUN211E"
  332.             case "MRUN211F"
  333.             case "MRUN211G"
  334.             case "ARRAY"
  335.             case "HOST"
  336.             case "HOSTUTIL"
  337.             case "USER"
  338.             case "SUBS"
  339.             case "MAIL"
  340.             endcase
  341.             default
  342.                 rewind ScriptFile
  343.                 fgets ScriptFile ScriptLine
  344.                 while not NULLSTR ScriptLine
  345.                     if strcmp ScriptLine NextScript
  346.                         exitswitch
  347.                     endif
  348.                     fgets ScriptFile ScriptLine
  349.                 endwhile
  350.                 fputs ScriptFile NextScript
  351.                 if NULLSTR ScriptName
  352.                     ScriptName = NextScript
  353.                 endif
  354.             endcase
  355.         endswitch
  356.         findnext
  357.     endwhile
  358.     fclose ScriptFile
  359. endproc
  360.  
  361.  
  362. #comment
  363. *********************************************************************
  364. * 
  365. * SCRIPTBOX()
  366. * 
  367. * Called by adddoscript()
  368. * 
  369. * Displays the Execute Script dialog box.
  370. * 
  371. *********************************************************************
  372. #endcomment
  373.  
  374. proc scriptbox
  375. PermRadio = 2
  376. destroydlg
  377. ScriptName = "terminal"
  378. HelpPage = 12
  379. dialogbox 92 60 180 135 15 "Execute Script" HELPID HelpPage
  380.    text  14 36 64 8 right "Available Scripts:"
  381.    fcombobox 82 34 76 42 ScriptList ScriptName sort
  382.    text  20 54 136 22 left "WARNING:  Scripts must not alter \
  383. global variables s0-s9 and i0-i9!!!"
  384.    radiobutton 17 85 62 14 "Permanent" PermRadio
  385.    radiobutton 17 107 62 14 "Temporary" endgroup
  386.    pushbutton 114 85 40 14 "&Add" normal default
  387.    pushbutton 114 107 40 14 "&Done" normal
  388.    text  14 11 64 8 right "Execute Script at:"
  389.    combobox 82 9 76 42 BBSList BBSChoice sort
  390. enddialog
  391. endproc
  392.  
  393.  
  394. #comment
  395. *********************************************************************
  396. * 
  397. * SHOWABOUT()
  398. * 
  399. * Called by main()
  400. * 
  401. * Calls aboutbox()
  402. * 
  403. * Displays the About MailRun dialog box.
  404. * 
  405. *********************************************************************
  406. #endcomment
  407.  
  408. proc showabout
  409. integer dialogstatus
  410.     statmsg ""
  411.     aboutbox()
  412.     dialogstatus = $DIALOG
  413.     while dialogstatus != 1
  414.         dialogstatus = $DIALOG
  415.     endwhile
  416.     exit
  417. endproc
  418.  
  419.  
  420. #comment
  421. *********************************************************************
  422. * 
  423. * ABOUTBOX()
  424. * 
  425. * Called by showabout()
  426. * 
  427. * Calls makefullname()
  428. * 
  429. * Displays the About MailRun dialog box.
  430. * 
  431. *********************************************************************
  432. #endcomment
  433.  
  434. proc aboutbox
  435. destroydlg
  436. HelpPage = 1
  437. MRunIcons = makefullname(MailRunDir, "MRUNICON.DLL")
  438. IconIndex = 17
  439. dialogbox 55 55 220 151 15 "About MailRun" HELPID HelpPage
  440.    text  42 14 136 27 center "MailRun`r`nVersion 2.11`r`n\
  441. Copyright ⌐ 1992-1993 Gerald P. Sully"
  442.    text  20 48 180 28 left "If you use MailRun with any regularity, \
  443. ease your aching conscience by helping out a starving author.`r`n\
  444. Send $15 to:"
  445.    icon 160 82 MRunIcons IconIndex
  446.    text  20 80 120 44 left "Jerry Sully`r`n841 Solano Ave. #2`r`n\
  447. Albany, CA  94706`r`n`r`nThank you for your support!"
  448.    pushbutton 20 128 180 14 "I promise I'll send $15 as soon as I \
  449. can afford it!" cancel
  450. enddialog
  451. endproc
  452.